#version 330

uniform sampler2D tex;
uniform sampler2D shadowmap;
uniform vec3 viewPos;
uniform vec3 sun;
uniform vec4 fogColor;


in vec4 fragPos;
in vec4 fragPosLightspace;
in vec2 fragTexCoord;
in vec3 fragNormal;

out vec4 outputColor;


const float gamma = 2.2;

const float ambient = 0.3, specularStrength = 0.5, specularShininess = 32;
const float fogDensity = .00003;


float light;
vec4 texpixel, color;
void lightSun();
float lightSunShadow();
void lightPoint(int i);


void main() {

	texpixel = texture(tex, fragTexCoord);
	if (texpixel.a < 1e-3)
		discard;
	texpixel.rgb = pow(texpixel.rgb, vec3(gamma));

	light = ambient;

	lightSun();

	color += vec4(texpixel.rgb * light, 0.0f);
	color.a = texpixel.a;

	float z = gl_FragCoord.z / gl_FragCoord.w;
	float fog = clamp(exp(-fogDensity * z * z), 0.2, 1);

	outputColor = mix(fogColor, color, fog);
	//outputColor.rgb = pow(outputColor.rgb, vec3(1.0/gamma));
}

void lightSun() {
	/* Diffuse */
	vec3 lightDir = sun;
	float diffuse = max(dot(fragNormal, lightDir), 0.0f);

	/* Specular */
	vec3 viewDir = normalize(viewPos - fragPos.xyz);
	vec3 reflectDir = reflect(-lightDir, fragNormal);
	float specular = specularStrength * pow(max(dot(viewDir, reflectDir), 0.0), specularShininess);

	float shadow = lightSunShadow();
	light += diffuse * shadow;
	color += vec4(vec3(specular), 0.0f) * shadow;
}

float lightSunShadow() {
	/* Shadow */
	float bias = max(0.005 * (1.0 - dot(fragNormal, sun)), 0.0005);
	vec3 projCoords = fragPosLightspace.xyz / fragPosLightspace.w;
	projCoords = projCoords*0.5 + 0.5;
	//float closestDepth = texture(shadowmap, projCoords.xy).r;
	float currentDepth = projCoords.z;
	float shadow = 0;

	if (currentDepth > 1.0f || currentDepth < 0.0f)
		return 1.0f;

	vec2 texelSize = 1.0 / textureSize(shadowmap, 0);
	for (int x=-1; x<=1; ++x)
		for (int y=-1; y<=1; ++y) {
			float pcfDepth = texture(shadowmap, projCoords.xy + vec2(x,y)*texelSize).r;
			shadow += currentDepth-bias < pcfDepth ? 1.0f : 0.0f;
		}
	shadow /= 9.0f;
	return shadow;
}
